quote:

I hope you'll remember the little people.

quote:

Originally posted by BN:
I'm going to be rich!

quote:

program Calendar2(input,output);
{Displays a calendar for any month from January 1901 through December 2999.}
type WeekDay = 0..6; {Sunday is 0.}
MonthDay = 1..31;
MonthInteger = 1..12;
YearInteger = 1901..2999; {The simple leap-year calculation used doesn't work for 1900 or 3000.}
var Month : MonthInteger;
Year : YearInteger;
Ans : char;

function NewYearsDay(Year: YearInteger): Weekday;
{Returns a code for the day of the week for January 1 of the specified year.
The function does not work correctly if you change th type of
Year to integer and use years such as 1900 or 3000.}
const JanFirst1901 = 2; {Tuesday}
var ElapsedYears: integer;
LeapYearCount: integer;
begin {NewYearsDay}
ElapsedYears := Year - 1901;
LeapYearCount := (ElapsedYears div 4);
NewYearsDay := (JanFirst1901 + ElapsedYears + LeapYearCount) mod 7
end; {NewYearsDay}

function LeapYear(Year: YearInteger): boolean;
{Returns true if Year is a leap year. This function will not work
correctly if the type of Year is changed to the type integer. For example,
1900 and 3000 would both return true, but neither one is a leap year.}
begin {LeapYear}
LeapYear := (Year mod 4) = 0
end; {LeapYear}

function TotalDays(Month: MonthInteger; Year: YearInteger): MonthDay;
{Returns the number of days in the Month of the given Year.}
begin {TotalDays}
case Month of
4, 6, 9, 11: TotalDays := 30;
1, 3, 5, 7, 8, 10, 12: TotalDays := 31;
2: if not LeapYear(Year) then
TotalDays := 28
else
TotalDays := 29;
end; {case}
end; {TotalDays}

function Dayone(Month: MonthInteger; Year: YearInteger): Weekday;
{Returns a code for the day of the week for the first day of the Month
of the specified Year. Calls the functions NewYearssDay and TotalDays.}
var DayCount: integer;
PastMonth: MonthInteger;
begin {DayOne}
DayCount := NewYearsDay(Year);
for PastMonth := 1 to (Month - 1) do
DayCount := DayCount + TotalDays(PastMonth, Year);
DayOne := DayCount mod 7;
end; {DayOne}

procedure DisplayMonth(NumberOfDays: MonthDay; Firstday: WeekDay);
{Displays the usual layout for a month with NumberOfDays days in it.
FirsDay codes the first day of the month. 0 for Sunday. 1 for Monday, etc.
The procedure code is identiacl to that in Figure 7.19, but the parameter
types have been changed to subrange types in order to provide additional
check for errors in the program.}
const Width = 4; {Field width for one day of the calendar.}
Blank = ' ';
var DayCount, CountAll : integer;
begin {DisplayMonth}
writeln('Sun':Width,'Mon':Width,'Tue':Width,'Wed':Width,'Thu':Width,'Fri':Width,'Sat':Width);
for CountAll := 0 to (FirstDay - 1) do
write(Blank:Width);
CountAll := FirstDay; {for the initial blanks}
for DayCount := 1 to NumberOfDays do
begin {for}
CountAll := CountAll + 1;
{If (CountAll mod7) = 0, then day number DayCount is a Saturday.}
write(DayCount:Width);
if (CountAll mod 7) = 0 then
writeln;
end; {for}
writeln;
end; {DisplayMonth}

begin {Program}
writeln('This program will display the calendar for');
writeln('any month from the years 1901 to 2999.');
repeat
writeln('Enter month and year as two integers: ');
readln(Month,Year);
writeln('Month ':12, Month:2, ' Year ', Year:4);
DisplayMonth(TotalDays(Month,Year), DayOne(Month,Year));
writeln('Do you want to see another month? (y/n)');
readln(Ans);
until (Ans = 'n') or (Ans = 'N');
writeln('Have a good month!');
end. {Program}